type
  // Тип селектора
  TSelectorType = (stUnknown,
                  stBoolean,
                  stInteger,
                  stColor,
                  stString,
                  stFont);

  // --------- Общий класс-родитель настроек -------------
  TCustomOption = class
  private
    FCaption: string;            // Название настройки, отображаемое на форме
    FName: string;                // Имя ноды в XML-файле <Setting>
    FSelectorType: TSelectorType; // Тип опции
    FGroupIndex: Integer;        // Идентификатор группы (для разделения)
    FVisisble: Boolean;          // Флаг вилимости опции. Если True, то под опцию создаётся контрол
  public
    constructor Create(const ACaption, AName: string); virtual;
    procedure SaveToXml(AParentNode: TXMLItem); virtual; abstract;  // Сохранение
    procedure LoadFromXml(ANode: TXMLItem); virtual; abstract;      // Загрузка
    property Name: string read FName;                                // Имя ноды в XML-файле <Setting>
    property Caption: string read FCaption;                          // Название настройки, отображаемое на форме
    property SelectorType: TSelectorType read FSelectorType write FSelectorType; // Тип опции
    property GroupIndex: Integer read FGroupIndex write FGroupIndex; // Идентификатор группы (для разделения)
    property Visible: Boolean read FVisisble write FVisisble;        // Флаг вилимости опции. Если True, то под опцию создаётся контрол
  end;

 
type
  // ------- Класс для хранения Boolean ----------
  TBooleanOption = class(TCustomOption)
  private
    FValue: Boolean;  // Хранимое значение
  public
    procedure SaveToXml(AParentNode: TXMLItem); override;  // Сохранение
    procedure LoadFromXml(ANode: TXMLItem); override;      // Загрузка
    property Value: Boolean read FValue write FValue;      // Хранимое значение
  end;

  // ------- Класс для хранения Integer ----------
  TIntegerOption = class(TCustomOption)
  private
    FValue: Integer;  // Хранимое значение
  public
    procedure SaveToXml(AParentNode: TXMLItem); override;  // Сохранение
    procedure LoadFromXml(ANode: TXMLItem); override;      // Загрузка
    property Value: Integer read FValue write FValue;      // Хранимое значение
  end;

  // -------- Класс для хранения TColor -----------
  TColorOption = class(TCustomOption)
  private
    FValue: TColor;  // Хранимое значение
  public
    procedure SaveToXml(AParentNode: TXMLItem); override;  // Сохранение
    procedure LoadFromXml(ANode: TXMLItem); override;      // Загрузка
    property Value: TColor read FValue write FValue;      // Хранимое значение
  end;

  // ------- Класс для хранения string -------------
  TStringOption = class(TCustomOption)
  private
    FValue: string;  // Хранимое значение
  public
    procedure SaveToXml(AParentNode: TXMLItem); override;  // Сохранение
    procedure LoadFromXml(ANode: TXMLItem); override;      // Загрузка
    property Value: string read FValue write FValue;      // Хранимое значение
  end;

  // ------- Класс для хранения TFont -------------
  TFontOption = class(TCustomOption)
  private
    FValue: TFont;  // Хранимое значение
    FFontEffects: Boolean; // Флаг показа свойст шрифта: Подчёркнутый, зачёркнутый, цвет
  public
    constructor Create(const ACaption, AName: string); override;
    destructor Destroy(); override;
    procedure SaveToXml(AParentNode: TXMLItem); override;  // Сохранение
    procedure LoadFromXml(ANode: TXMLItem); override;      // Загрузка
    property Value: TFont read FValue;                    // Хранимое значение
    property FontEffects: Boolean read FFontEffects write FFontEffects;
  end;

 
// ============= Класс - Настройки программы ================
  TProgramSettings = class
  private
    FOptions: TObjectList;            // Список настроек
    FFileName: string;                // Имя файла для хранения настроек
    function GetOptionsCount: Integer; // Количество настроек
    function GetOptionByIndex(const Index: Integer): TCustomOption;  // Получение опции по индексу
    function GetOptionByName(const AName: string): TCustomOption;    // Получение опции по имени ноды в XML-файле
    function GetOptionByCaption(const ACaption: string): TCustomOption; // Получение опции по названию, отображаемому на форме
  public
    constructor Create();
    destructor Destroy(); override;

    function NewOption(const ACaption, AName: string;            // Добавление опции в список
                      const ASelectorType: TSelectorType;
                      const AGroupIndex: Integer): TCustomOption;

    function SaveToXml(): Boolean;                                // Сохранение
    function LoadFromXml(): Boolean;                              // Загрузка

    property OptionsCount: Integer read GetOptionsCount;
    property OptionsByIndex[const Index: Integer]: TCustomOption read GetOptionByIndex; default; // опции по индексу
    property OptionsByName[const AName: string]: TCustomOption read GetOptionByName;            // опции по имени ноды в XML-файле
    property OptionsByCaption[const ACaption: string]: TCustomOption read GetOptionByCaption;    // опции по названию, отображаемому на форме
  end;

constructor TProgramSettings.Create;
var
  Index: Integer;
  Option: TCustomOption;
begin
  // Имя файла для хранения настроек
  FFileName:= ExtractFilePath(ParamStr(0)) + 'Settings.xml';

  // Создание объектов
  FOptions:= TObjectList.Create(True);

  // Добаляю группу "Цвета"
  for Index:= 0 to High(ColorSettingsNames) do
    begin
      Option:= NewOption(ColorSettingsNames[Index, 0], // Название (Caption)
                        ColorSettingsNames[Index, 1], // Имя (Name)
                        stColor,                      // Тип селектора
                        ColorSettingsGroup);          // Номер группы
      TColorOption(Option).Value:= ColorSettingsDefaults[Index];  // Значение по умолчанию
    end;

  // Добавляю группу "Шрифты"
  for Index:= 0 to High(FontSettingsNames) do
    begin
      Option:= NewOption(FontSettingsNames[Index, 0],  // Название (Caption)
                        FontSettingsNames[Index, 1],  // Имя (Name)
                        stFont,                        // Тип селектора
                        FontSettingsGroup);            // Номер группы

      TFontOption(Option).FontEffects:= FontEffectsVisible[Index]; // Флаги показа свойст шрифта                 
    end;

  // Добавляю группу "Интерфейс"
  for Index:= 0 to High(InterfaceSettingsNames) do
    begin
      Option:= NewOption(InterfaceSettingsNames[Index, 0],  // Название (Caption)
                        InterfaceSettingsNames[Index, 1],  // Имя (Name)
                        stBoolean,                          // Тип селектора
                        InterfaceSettingsGroup);            // Номер группы


      TBooleanOption(Option).Value:= InterfaceSettingsDefaults[Index]; // Значение по умолчанию
    end;

  // Создание невидимых опций
  NewOption('Имя последнего открытого файла',
            nLastFileName,
            stString,
            InvisibleGroup).Visible:= False; // имя последнего открытого файла
end;